Some users like to keep a history of all appointments, including canceled meetings. However, when you delete the cancellation notice from your Inbox, it deletes the meeting from the calendar too.

I want to keep canceled meetings on my calendar as it is useful when reviewing my calendar and wondering why I didn’t attend other meetings.

Most people want to clear out their Inbox and delete the cancellation notice, but to avoid removing the canceled meeting from your calendar, you need to keep the meeting cancellation notice. As long as the meeting cancellation notice remains in your mailbox and out of the Deleted Items folder, the meeting item remains on your calendar.

Solutions

Meeting invitees have two options: They can create a folder to move the meeting cancellation notices into or they can use use a run a script rule to convert canceled meetings into appointments when the cancellation notices arrive. This will allow to you delete the meeting cancellation notice.

These options won't work for the meeting organizer. While you can get the cancelled meeting from the Deleted Items folder and move it back to the calendar, it's still a meeting. If you decide to delete it, Outlook will want to send another cancellation.

If the organizer needs to keep a copy of canceled meetings, he needs to create a copy of the meeting before canceling it. In Outlook 2010, right click and drag the meeting to a different calendar folder to create a copy. On page 2, we have a code sample organizers can use to copy the meeting request before canceling it.

Canceled meetings are left on Resource calendars. See Remove Canceled Meeting Requests from Resource Calendarfor a VBA sample that can remove the cancellation notices from Resource calendars.

Run a Script Rule to Convert a Canceled Meeting to an Appointment

Open Outlook's VBA editor (Alt+F11), expand Microsoft Office Outlook Objects then double click on ThisOutlookSession. Type or paste the code into the module, then create the rule with the 'run script' Action and select this script.

Sub CopyMeetingtoAppointment(oRequest As MeetingItem)

If oRequest.MessageClass <> "IPM.Schedule.Meeting.Canceled" Then
  Exit Sub
End If

Dim oAppt As AppointmentItem
Dim cAppt As AppointmentItem

Set cAppt = oRequest.GetAssociatedAppointment(True)
Set oAppt = Application.CreateItem(olAppointmentItem)

'I added (Rule) to the subject so I could see the rule was working. 
    oAppt.Subject = "(Rule) Canceled: " & cAppt.Subject
    oAppt.Start = cAppt.Start
    oAppt.Duration = cAppt.Duration
    oAppt.Location = cAppt.Location
    oAppt.Display
    oAppt.Save

    Set oAppt = Nothing
    Set cAppt = Nothing
End Sub

Macro for Organizers to Copy then Cancel Meetings

Organizers would use this code to copy the details to an appointment form before canceling the appointment. To avoid clicking one button to copy the meeting details and then the cancel and send buttons to complete the steps, the code does that for you. However, if you want the option of just copying a meeting as an appointment, without canceling it, remove the three lines that cancels & sends the update then deletes the meeting from your calendar.

This code works with either selected meetings or opened meeting forms.

Open Outlook's VBA editor (Alt+F11), expand Microsoft Office Outlook Objects then double click on ThisOutlookSession. Type or paste the code into the module, then create a button in Outlook's main interface and on an opened appointment form and assign the macro to it.

Sub CopyBeforeCancel()

Dim oAppt As AppointmentItem
Dim cAppt As AppointmentItem

Set cAppt = GetCurrentItem()
Set oAppt = Application.CreateItem(olAppointmentItem)
    
    
    oAppt.Subject = "(Rule) Canceled: " & cAppt.Subject
    oAppt.Start = cAppt.Start
    oAppt.Duration = cAppt.Duration
    oAppt.Location = cAppt.Location
    oAppt.Save

'This code cancels the meeting and sends the cancellation.
    cAppt.MeetingStatus = olMeetingCanceled
    cAppt.Send
    cAppt.Delete
    
    
    Set oAppt = Nothing
    Set cAppt = Nothing

End Sub

Function GetCurrentItem() As Object
    Dim objApp As Outlook.Application
         
    Set objApp = Application
    On Error Resume Next
    Select Case TypeName(objApp.ActiveWindow)
        Case "Explorer"
            Set GetCurrentItem = objApp.ActiveExplorer.Selection.Item(1)
        Case "Inspector"
            Set GetCurrentItem = objApp.ActiveInspector.CurrentItem
    End Select
     
    Set objApp = Nothing
End Function

This next piece code code copies a meeting to an appointment and moves it to a different calendar. This is useful for iCloud users whose meetings are resent when they add them to the iCloud.

Copy a meeting to a different calendar

This code sample opens the folder picker dialog for you to select the Calendar folder.

Sub CopyMeetingasApt()

Dim objDestCal As Outlook.MAPIFolder
Dim objNS As Outlook.NameSpace
Dim oAppt As AppointmentItem
Dim cAppt As AppointmentItem

Set objNS = Application.GetNamespace("MAPI")
Set cAppt = GetCurrentItem()
Set oAppt = Application.CreateItem(olAppointmentItem)

    
    oAppt.Subject = "(Rule) Canceled: " & cAppt.Subject
    oAppt.Start = cAppt.Start
    oAppt.Duration = cAppt.Duration
    oAppt.Location = cAppt.Location
    oAppt.Save

Set objDestCal = objNS.PickFolder
oAppt.Move objDestCal

    
    Set objDestCal = Nothing
    Set objNS = Nothing
    Set oAppt = Nothing
    Set cAppt = Nothing

End Sub

Function GetCurrentItem() As Object
    Dim objApp As Outlook.Application
         
    Set objApp = Application
    On Error Resume Next
    Select Case TypeName(objApp.ActiveWindow)
        Case "Explorer"
            Set GetCurrentItem = objApp.ActiveExplorer.Selection.Item(1)
        Case "Inspector"
            Set GetCurrentItem = objApp.ActiveInspector.CurrentItem
    End Select
     
    Set objApp = Nothing
End Function