A user wanted to know how to sort email messages by domain. Although you can filter by domain simply by typing the domain name in the address field, you can't sort as easily.

You can create a custom Formula field using this formula: right([SearchFromEmail],len([SearchFromEmail])-InStr(1,[SearchFromEmail],"@"))

Unfortunately, you can't sort by formula fields. However, custom Text fields are sortable and you can use a macro to add the domain to the custom field.

How to display the sender's email address in Outlook to add the sender's email address field to the view.

To use the first macro, select the messages then run the macro. To add the domain field to messages as they arrive, you'll need to use the run a script rule below.

Macro for selected messages

Public Sub SetDomain()
    ' From http://slipstick.me/1
    Dim currentExplorer As Explorer
    Dim Selection As Selection
    Dim obj As Object
    Dim objProp As Outlook.UserProperty
    Dim strDomain
    
    
    Set currentExplorer = Application.ActiveExplorer
    Set Selection = currentExplorer.Selection

    On Error Resume Next

    For Each obj In Selection
         Set objMail = obj
         
           strDomain = Right(objMail.SenderEmailAddress, Len(objMail.SenderEmailAddress) - InStr(objMail.SenderEmailAddress, "@"))
         Set objProp = objMail.UserProperties.Add("Domain", olText, True)
         objProp.Value = strDomain
        objMail.Save
 
        Err.Clear
    Next
 
    Set currentExplorer = Nothing
    Set obj = Nothing
    Set Selection = Nothing
End Sub

If you use Exchange server, the field will contain the Exchange x.500 address for mail from Internal senders. The easiest fix is to use an if statement to look for an @ sign. No @ sign means it's internal email. You can then enter your domain for these senders or use their alias.

For Each obj In Selection
         Set objMail = obj
         
  Set objProp = objMail.UserProperties.Add("Domain", olText, True)
    If InStr(1, objMail.SenderEmailAddress, "@") > 0 Then
         strDomain = Right(objMail.SenderEmailAddress, Len(objMail.SenderEmailAddress) - InStr(objMail.SenderEmailAddress, "@"))
     Else
        ' strDomain = "yourdomain.com"
        ' use this for the alias - you may need to use /cn in on-prem
         strDomain = Right(objMail.SenderEmailAddress, Len(objMail.SenderEmailAddress) - InStrRev(objMail.SenderEmailAddress, "-"))
    End If

  objProp.Value = strDomain

Create the custom field and add it to your view

To add the custom field to the view follow these steps:

1. Close or reduce the size of the reading pane so the From, Subject, Received date and other fields are on one line
2. Right click on the row of field names and then choose Field Chooser from the menu
3. Click New and type Domain in the Name field
4. If User-defined field in [folder] is not visible, select it, then drag the newly created Domain field to the row of field names

Click on the Domain name to sort..

Run a script rule

Use the following macro in a run a script rule. If you need instructions, see Outlook's Rules and Alerts: Run a Script.

Public Sub SetDomainScript(Item As Outlook.MailItem)
    ' Fromhttp://slipstick.me/1
    Dim objProp As Outlook.UserProperty
    Dim strDomain
       strDomain = Right(objMail.SenderEmailAddress, Len(objMail.SenderEmailAddress) - InStr(1, objMail.SenderEmailAddress, "@"))
         Set objProp = Item.UserProperties.Add("Domain", olText, True)
         objProp.Value = strDomain
        Item.Save
        
 End Sub

Add the Sent To domain

This macro gets the first email address a message is sent to and adds it to the Domain field. You could loop through the entire recipient list and get all addresses or domains, but the list is a simple text list and sorts by the first domain, making it less useful.

This macro works on both incoming messages and messages in your sent folder.

Public Sub SetToDomain()
    ' Fromhttp://slipstick.me/1
    Dim currentExplorer As Explorer
    Dim Selection As Selection
    Dim obj As Object
    Dim objProp As Outlook.UserProperty
    Dim strDomain

 Dim recips As Outlook.Recipients
 Dim recip As Outlook.Recipient
 Dim pa As Outlook.propertyAccessor
 Dim Address As String
 Dim lLen

 Const PR_SMTP_ADDRESS As String = "http://schemas.microsoft.com/mapi/proptag/0x39FE001E"
    
    Set currentExplorer = Application.ActiveExplorer
    Set Selection = currentExplorer.Selection
 
    On Error Resume Next
 
    For Each obj In Selection
         Set objMail = obj
          
' This gets the first recipient's address
 Set recips = objMail.Recipients
 Set recip = recips.Item(1)
 Set pa = recip.propertyAccessor
  
 Address = LCase(pa.GetProperty(PR_SMTP_ADDRESS))
 lLen = Len(Address) - InStrRev(Address, "@")
          
         strDomain = Right(Address, lLen)
         Set objProp = objMail.UserProperties.Add("Domain", olText, True)
         objProp.Value = strDomain
        objMail.Save
  
        Err.Clear
    Next
  
    Set currentExplorer = Nothing
    Set obj = Nothing
    Set Selection = Nothing
End Sub

Create other fields

You can customize the macro to work with other fields. In this example, I'm adding a text field containing the received date formatted in Month day format. Don't forget to use a unique name for the field!

Tip: if you want to sort by a date field, use "yyyy mm dd" for the date format, use olDateTime instead of oltext.

strDomain = Format(objMail.ReceivedTime, "mm/dd/yyyy")
Set objProp = objMail.UserProperties.Add("MyDate", olDateTime, True)

Public Sub SetDate()
    ' Fromhttp://slipstick.me/1
    Dim currentExplorer As Explorer
    Dim Selection As Selection
    Dim obj As Object
    Dim objProp As Outlook.UserProperty
    Dim strDomain
    Dim objMail As MailItem
     
    Set currentExplorer = Application.ActiveExplorer
    Set Selection = currentExplorer.Selection
 
    On Error Resume Next
 
    For Each obj In Selection
         Set objMail = obj
          
   ' make changes here
      strDomain = Format(objMail.ReceivedTime, "MMM dd")
         Set objProp = objMail.UserProperties.Add("MyDate", olText, True)
         objProp.value = strDomain
        objMail.Save
  
        Err.Clear
    Next
  
    Set currentExplorer = Nothing
    Set obj = Nothing
    Set Selection = Nothing
End Sub

To use the macros with other Outlook item types, you only need to change the item type in the Dim statements:
Dim objMail As TaskItem

And the field:
strDomain = Format(objMail.CreationTime, "MMM dd yyyy")

And, of course, you might want to change the field name and type:
Set objProp = objMail.UserProperties.Add("ThisField", olDateTime, True)

Yes, it would be less confusing to use a generic object name, like objItem, but as long as the field is supported by the declared object, it will work.

How to use macros

First: You will need macro security set to low during testing.

To check your macro security in Outlook 2010 or 2013, go to File, Options, Trust Center and open Trust Center Settings, and change the Macro Settings. In Outlook 2007 and older, it’s at Tools, Macro Security.

After you test the macro and see that it works, you can either leave macro security set to low or sign the macro.

Open the VBA Editor by pressing Alt+F11 on your keyboard.

To put the code in a module:

1. Right click on Project1 and choose Insert > Module
2. Copy and paste the macro into the new module.

More information as well as screenshots are at How to use the VBA Editor