Automatically BCC All Messages

Outlook doesn't have a built in method you can use to automatically include yourself (or other email address) in the BCC field when you send a new message. You can use Rules Wizard to CC and address but not to send a BCC.

To BCC the message, you need to either use VBA or a utility listed below.

Always BCC Code Sample

Basic VBA instructions are below, instructions with screenshots are at How to use Outlook's VBA Editor .

Private Sub Application_ItemSend(ByVal Item As Object, _
                                 Cancel As Boolean)
    Dim objRecip As Recipient
    Dim strMsg As String
    Dim res As Integer
    Dim strBcc As String
    On Error Resume Next

    ' #### USER OPTIONS ####
    ' address for Bcc -- must be SMTP address 
    ' or resolvable to a name in the address book
    strBcc = "address@domain.com"

    Set objRecip = Item.Recipients.Add(strBcc)
    objRecip.Type = olBCC
    If Not objRecip.Resolve Then
        strMsg = "Could not resolve the Bcc recipient. " & _
                 "Do you want to send the message?"
        res = MsgBox(strMsg, vbYesNo + vbDefaultButton1, _
                "Could Not Resolve Bcc")
        If res = vbNo Then
            Cancel = True
        End If
    End If

    Set objRecip = Nothing
End Sub

BCC Some but not All Messages

If you need to BCC, some but not all, messages, you'll need to use an IF statement to filter the messages. While you can filter on To, subject, or category fields, if you need to use series of If statements, filtering by category may be the easiest.

This code block BCCs one address if the category is Personal, another if the category is Important and exits if there is no category. It could easily be switched around to exit if there is a category and BCC everything else.

To add a category to email, click on the Expander in the Tags group and choose the Category from the options dialog. You could also use a macro to add a specific category to the ribbon for easy access. Get the code from Adding Categories when Composing Email.

  Private Sub Application_ItemSend(ByVal Item As Object, _
                                 Cancel As Boolean)

    Dim objRecip As Recipient
    Dim strMsg As String
    Dim res As Integer
    Dim strBcc As String
    On Error Resume Next

  If Item.Categories = "Personal" Then
      strBcc = "address@domain.com"
     ElseIf Item.Categories = "Important" Then
      strBcc = "new@address.com"
     Else
      Exit Sub
  End If
    
  Set objRecip = Item.Recipients.Add(strBcc)
    objRecip.Type = olBCC
    If Not objRecip.Resolve Then
        strMsg = "Could not resolve the Bcc recipient. " & _
                 "Do you want to send the message?"
        res = MsgBox(strMsg, vbYesNo + vbDefaultButton1, _
                "Could Not Resolve Bcc")
        If res = vbNo Then
            Cancel = True
        End If
    End If

    Set objRecip = Nothing
End Sub

BCC Messages sent From a Specific Account

If you have multiple accounts in your profile and only want to BCC messages sent through a specific account, use an IF statement to check the SendUsingAccount value. Be sure to use the account name as it appears in the From field or Account Settings dialog.

To BCC from all but one account, replace the = sign in the If statement with <>.

Private Sub Application_ItemSend(ByVal Item As Object, _
                                 Cancel As Boolean)
    Dim objRecip As Recipient
    Dim strMsg As String
    Dim res As Integer
    Dim strBcc As String
    On Error Resume Next

    strBcc = "alias@domain.com"

' Use the account name as it appears in Account Settings
If Item.SendUsingAccount = "account@domain.com" Then

    Set objRecip = Item.Recipients.Add(strBcc)
    objRecip.Type = olBCC
    If Not objRecip.Resolve Then
        strMsg = "Could not resolve the Bcc recipient. " & _
                 "Do you want to send the message?"
        res = MsgBox(strMsg, vbYesNo + vbDefaultButton1, _
                "Could Not Resolve Bcc")
        If res = vbNo Then
            Cancel = True
        End If
    End If
    
End If

    Set objRecip = Nothing
End Sub

How to use VBA

You will need macro security set to low during testing. To check your macro security in Outlook 2010 and up, go to File, Options, Trust Center and open Trust Center Settings, Macro Settings. In Outlook 2007 and older, it's at Tools, Macro Security.

After you test the macro and see that it works, you can either leave macro security set to low or sign the macro.

1. Open the VBA Editor using Alt+F11.
2. Expand Project1 and double click on ThisOutlookSession.
3. Copy then paste the macro into ThisOutlookSession. (Click within the code, Select All using Ctrl+A, Ctrl+C to copy, Ctrl+V to paste.)

Don't forget to replace address@domain.com with the correct address.

Automatically BCC using Smartphones

While not "an Outlook problem", automatically BCCing when sending mail from a smart phone is a popular feature. Because the mail goes directly to the SMTP server, Outlook's ability (or lack of it) is not a factor; it's all about what the smart phone software supports.

IPhone and iPad users can set the device to always BCC your address in Options > Mail, Calendar, and Contacts.

Automatically BCC using Exchange Transport rules

Administrators of Exchange Server can configure a transport rule, or in Office 365, a Mail flow rule, to BCC messages to another address, bypassing the need for VBA or other solutions (and without the user's knowledge).

Transport and Mail flow rules can be created and configured using a cmdlet or from the Exchange System Manager console.