Use this macro to select multiple calendars and open them in overlay mode. If you are using iCloud and don't want the iCloud calendars selected by default, you can use this method to deselect the iCloud calendars. See Deselect iCloud Calendars for more information and the necessary code.

This code sample assumes that the calendars are all in the My Calendars group.

If the calendars are all in another group, you can use this line to identify the group and select the calendars in it:
Set objGroup = .Item("group name")

In this code sample, I'm opening calendars #1, 3, and 4 in the My Calendars group. To open 2 and 5 (New Stuff and a mailbox Calendar in the screenshot), I'd use Case 2, 5

When you use Outlook 2013 and all of the calendars are in one group, you can select the group to show all.

To use, set macro security to low, open the VBA editor by pressing Alt+F11 then paste this into a new module. Assign it to a ribbon or toolbar button and run. More complete instructions are at How to use the VBA Editor.

To use a specific view, see set a view at the end of this article.

Sub SelectCalendars()
    Dim objPane As Outlook.NavigationPane
    Dim objModule As Outlook.CalendarModule
    Dim objGroup As Outlook.NavigationGroup
    Dim objNavFolder As Outlook.NavigationFolder
    Dim objCalendar As Folder
    Dim objFolder As Folder
    
    Dim i As Integer
    
    Set Application.ActiveExplorer.CurrentFolder = Session.GetDefaultFolder(olFolderCalendar)
    DoEvents
    
    Set objCalendar = Session.GetDefaultFolder(olFolderCalendar)
    Set objPane = Application.ActiveExplorer.NavigationPane
    Set objModule = objPane.Modules.GetNavigationModule(olModuleCalendar)
    
    With objModule.NavigationGroups
        Set objGroup = .GetDefaultNavigationGroup(olMyFoldersGroup)

    ' To use a different group
       ' Set objGroup = .Item("group name")
    End With

    For i = 1 To objGroup.NavigationFolders.Count
        Set objNavFolder = objGroup.NavigationFolders.Item(i)
        Select Case i

        ' Enter the calendar index numbers you want to open
            Case 1, 3, 4
                objNavFolder.IsSelected = True
             
        ' Set to True to open side by side
                objNavFolder.IsSideBySide = False
            Case Else
                objNavFolder.IsSelected = False
        End Select
    Next

' set the view here

    Set objPane = Nothing
    Set objModule = Nothing
    Set objGroup = Nothing
    Set objNavFolder = Nothing
    Set objCalendar = Nothing
    Set objFolder = Nothing
End Sub

Automatically select specific calendars when switching to the calendar module

If you want to always have certain calendars selected when you switch to the calendar module, you can add an Application_Startup macro to the code. Every time you select the calendar module, the calendars listed in the Case statement will be selected.

To use this macro, add it to ThisOutlookSession. Click in the Application_Startup macro and press Run to enable it without restarting Outlook.

Dim WithEvents objPane As NavigationPane
  
Private Sub Application_Startup()
    Set objPane = Application.ActiveExplorer.NavigationPane
  
End Sub
  
Private Sub objPane_ModuleSwitch(ByVal CurrentModule As NavigationModule)

    Dim objPane As NavigationPane
    Dim objModule As CalendarModule
    Dim objGroup As NavigationGroup
    Dim objNavFolder As NavigationFolder
    Dim objCalendar As Folder
    Dim objFolder As Folder
     
    Dim i As Integer
     
    If CurrentModule.NavigationModuleType = olModuleCalendar Then
    Set Application.ActiveExplorer.CurrentFolder = Session.GetDefaultFolder(olFolderCalendar)
    DoEvents
     
    Set objCalendar = Session.GetDefaultFolder(olFolderCalendar)
    Set objPane = Application.ActiveExplorer.NavigationPane
    Set objModule = objPane.Modules.GetNavigationModule(olModuleCalendar)
     
    With objModule.NavigationGroups
        Set objGroup = .GetDefaultNavigationGroup(olMyFoldersGroup)
 
    ' To use a different group
       ' Set objGroup = .Item("group name")
    End With
 
    For i = 1 To objGroup.NavigationFolders.Count
        Set objNavFolder = objGroup.NavigationFolders.Item(i)
        Select Case i
 
        ' Enter the calendar index numbers you want to open
            Case 1, 3, 4
                objNavFolder.IsSelected = True
              
        ' Set to True to open side by side
                objNavFolder.IsSideBySide = False
            Case Else
                objNavFolder.IsSelected = False
        End Select
    Next

' set the view here

    End If

    Set objPane = Nothing
    Set objModule = Nothing
    Set objGroup = Nothing
    Set objNavFolder = Nothing
    Set objCalendar = Nothing
    Set objFolder = Nothing

End Sub

Select Specific Calendar When Outlook Starts

Outlook is starting with the user's Calendar and not the one we want selected.

If the calendar is in an account in your profile, you can select the calendar in File, Options, Advanced and select it as the startup folder. If it's not available to select, you might be able to use a command line switch to choose the correct calendar. See "Choose the Folder Outlook Starts Up In" for details.

This code selects a specific calendar when Outlook starts up. You need to set Outlook to start in the Calendar folder for it to work.

Private Sub Application_Startup()
  Dim objPane As NavigationPane
  Dim objModule As CalendarModule
  Dim objGroup As NavigationGroup
  Dim objNavFolder As NavigationFolder
 
  Set objPane = Application.ActiveExplorer.NavigationPane
  Set objModule = objPane.Modules.GetNavigationModule(olModuleCalendar)
 
  With objModule.NavigationGroups
  Set objGroup = .GetDefaultNavigationGroup(olMyFoldersGroup)
  End With
     On Error Resume Next
   Set objNavFolder = objGroup.NavigationFolders.Item(2)
       DoEvents
   objNavFolder.IsSelected = True
   objNavFolder.IsSideBySide = False
     DoEvents
   Set objNavFolder = objGroup.NavigationFolders.Item(1)
     objNavFolder.IsSelected = False

'set the view here

End Sub

Deselect iCloud Calendars

Many iCloud users don't appreciate that Apple has all iCloud calendars selected by default when you open Outlook. If you are one of these users, you can use the following code sample to deselect the iCloud calendars. Replace the block of code between With objModule.NavigationGroups and the last End If in the automatic macro above with the code below.

    With objModule.NavigationGroups
        Set objGroup = .Item("iCloud")
    End With
  
    For i = 1 To objGroup.NavigationFolders.Count
        Set objNavFolder = objGroup.NavigationFolders.Item(i)
        Select Case i
  
        ' Enter the calendar index numbers you want to close
            Case 1, 2
             If objNavFolder.IsSelected = True Then
                objNavFolder.IsSelected = False
             Else
             End If
        ' we'll deselect any we missed
           Case Else
               objNavFolder.IsSelected = False
        End Select
    Next

End If

Set a specific view on the Calendar

Outlook will generally use the last view you used on the calendar. If you want to use a specific view with the macros above, you can set the view in the code.

Add this code before the end of the macros above to set the calendar to the day view. If the macro has an End if at the end, add it before the End If.

 Dim objViews As Views
 Dim objView As View
 
Set objViews =  Application.ActiveExplorer.CurrentFolder.Views
 Set objView = objViews.Item("Calendar")
  With objView
      ' Set the calendar view to show a
      ' single day.
      .CalendarViewMode = olCalendarViewDay
  End With

 objView.Apply