Use a Macro to Attach Files to New Messages

This is a version of the macro at Insert the Newest HTML File. Instead of inserting the file as stationery, it adds the newest file as an attachment to a new message.

By changing the conditions in the IF statement, you can add files based on other conditions.
If fsoFile.DateLastModified > dtNew And Right(fsoFile.Name, 5) = ".docx" Then

The macro uses the Scripting Runtime to read the HTML file. You'll need to set a reference to it in the VB Editor's Tools, References dialog.

Sub AttachNewestFile()
' You need to set a reference to the scripting object
Dim objMail As Outlook.MailItem
Dim fso As Scripting.FileSystemObject
 
 Dim strFile As String
 Dim fsoFile As Scripting.File
 Dim fsoFldr As Scripting.Folder
 Dim dtNew As Date, sNew As String
 
 Set fso = New Scripting.FileSystemObject
 
 strFile = "C:\Users\Administrator\Documents\"
   
 Set fsoFldr = fso.GetFolder(strFile)
     
     For Each fsoFile In fsoFldr.Files
' check the extension and age
         If fsoFile.DateLastModified > dtNew And Right(fsoFile.Name, 5) = ".docx" Then
             sNew = fsoFile.Path
             dtNew = fsoFile.DateLastModified
             Debug.Print sNew & dtNew
         End If
     Next fsoFile
 
 'Create e-mail item
 Set objMail = Application.CreateItem(olMailItem)

 With objMail
 .BodyFormat = olFormatHTML
 .HTMLBody = "Here is the file you asked for"
 .Attachments.Add sNew
 .Display
 End With
End Sub

Attach Two Files

This version of the macro gets the newest document then finds the Excel with the same 4 first letters and inserts it into a new message.

Sub AttachTwoFiles()
' You need to set a reference to the scripting object
Dim objMail As Outlook.MailItem
Dim fso As Scripting.FileSystemObject
Dim fsoFile As Scripting.File
Dim fsoFldr As Scripting.Folder

 Dim strFilePath As String, strDoc As String
 Dim strExcel As String, strName As String
 Dim dtNew As Date, sNew As String
 
 Set fso = New Scripting.FileSystemObject
 
 strFilePath = "C:\Users\Administrator\Documents\"
   
 Set fsoFldr = fso.GetFolder(strFilePath)
     
     For Each fsoFile In fsoFldr.Files
         If fsoFile.DateLastModified > dtNew And Right(fsoFile.Name, 5) = ".docx" Then
             sNew = fsoFile.Path
             dtNew = fsoFile.DateLastModified
             Debug.Print sNew & dtNew
         End If
     Next fsoFile
     
 strDoc = sNew

strName = Right(sNew, Len(sNew) - Len(strFilePath))
strName = Left(strName, 4)

    For Each fsoFile In fsoFldr.Files
        If Left(fsoFile.Name, 4) = strName And Right(fsoFile.Name, 5) = ".xlsx" Then
            sNew = fsoFile.Path
        End If
    Next fsoFile

strExcel = sNew

 'Create e-mail item
 Set objMail = Application.CreateItem(olMailItem)

 With objMail
 .BodyFormat = olFormatHTML
 .HTMLBody = "Here is the file you asked for"
 .Attachments.Add strDoc
 .Attachments.Add strExcel
 .Display
 End With
End Sub

Attach Newest File to Message in Reading Pane

This macro works with Outlook 2013/2016's Reading Pane Compose feature and attaches the newest message to the reply in the Reading Pane.

Sub AttachNewestFileReadingPane()
' You need to set a reference to the scripting object
Dim objMail As Outlook.MailItem
Dim fso As Scripting.FileSystemObject
 
 Dim strFile As String
 Dim fsoFile As Scripting.File
 Dim fsoFldr As Scripting.Folder
 Dim dtNew As Date, sNew As String
 
 Dim exp As Explorer
 
 Set exp = Application.ActiveExplorer
 Set objMail = exp.ActiveInlineResponse
 If Not objMail Is Nothing Then
 
 Set fso = New Scripting.FileSystemObject
 
 strFile = "C:\Users\Diane\Documents\"
   
 Set fsoFldr = fso.GetFolder(strFile)
    
    For Each fsoFile In fsoFldr.Files
' check the age
         If fsoFile.DateCreated > dtNew Then
             sNew = fsoFile.Path
             dtNew = fsoFile.DateCreated
             Debug.Print sNew, dtNew
        End If

 Next fsoFile
 
    With objMail
        .Attachments.Add sNew
    End With
 End If
 
End Sub

Send a File to a Contact

This version of the macro sends a file named for the selected contact.

If you use a different filename format, for example "MarySmith" or "smith-mary", a simple macro edit will find the correct file:

strContact = objContact.FullName
Replace(strContact , " " , "")

Or use

strContact = lcase(objContact.lastName & "-" & objContact.firstName)

To use this macro, select the contact and run the macro.

Public Sub SendFileToContact()
Dim objApp As Outlook.Application
Dim objContact As ContactItem
 
Dim objMail As Outlook.MailItem
Dim fso As Scripting.FileSystemObject
Dim fsoFile As Scripting.File
Dim fsoFldr As Scripting.Folder

 Dim strFilePath As String, strDoc As String
 Dim strExcel As String, strName As String
 Dim strContact As String, sNew As String
 
Set objApp = Application
Set objContact = objApp.ActiveExplorer.Selection.Item(1)
strContact = objContact.FullName

Set fso = New Scripting.FileSystemObject
 
 strFilePath = "C:\Users\Administrator\Documents\"
   
 Set fsoFldr = fso.GetFolder(strFilePath)
     
     For Each fsoFile In fsoFldr.Files
         If Left(fsoFile.Name, Len(strContact)) = strContact And Right(fsoFile.Name, 5) = ".docx" Then
             sNew = fsoFile.Path
             Debug.Print sNew & dtNew
         End If
     Next fsoFile
     
 strDoc = sNew
 'Create e-mail item
 Set objMail = objApp.CreateItem(olMailItem)

 With objMail
 .To = objContact.Email1Address
 .BodyFormat = olFormatHTML
 .HTMLBody = "Here is the file you asked for"
 .Attachments.Add strDoc
 .Display
 End With
 
 Set objApp = Nothing
End Sub

How to use macros

First: You will need macro security set to low during testing.

To check your macro security in Outlook 2010 or 2013, go to File, Options, Trust Center and open Trust Center Settings, and change the Macro Settings. In Outlook 2007 and older, it’s at Tools, Macro Security.

After you test the macro and see that it works, you can either leave macro security set to low or sign the macro.

Open the VBA Editor by pressing Alt+F11 on your keyboard.

To put the code in a module:

1. Right click on Project1 and choose Insert > Module
2. Copy and paste the macro into the new module.

More information as well as screenshots are at How to use the VBA Editor