Also works with Outlook's Contact Groups (which are distribution lists with a friendlier name).

Run the macro, enter a contact's name in the Input box then press OK to create a list of the DLs the contact belongs to in a Word document. Use the exact name to return only that contact, or a partial name to return all contacts with similar names.

Leave the field blank and press OK to create a list of the members of all DLs.

A sample of the output when getting a list of all DLs and members (the name field is left blank). Click the image to see the full version with multiple DLs listed.:

This works in all versions of Outlook.

To search by email address, use GetMember(y).Address instead of GetMember(y).Name. (It's used 4 times in the code.) This will find all partial matches, for example, searching for 'poremsky' will find all addresses containing my last name anywhere in the email address.)

VBA Code sample

A text file of this macro is here.

Copy and paste this code into Outlook's VBA editor and set the references to Word.

    ' Code sample written by Graham Mayor -  Word MVP 
    ' //www.gmayor.com 

Sub ListNames()
Dim wdApp As Word.Application
Dim wdDoc As Word.Document
Dim myNameSpace As Outlook.NameSpace
Dim myFolder As Outlook.Folder 'use Outlook.MAPIFolder if Outlook.folder fails. 
Dim myDistList As Outlook.DistListItem
Dim myFolderItems As Outlook.Items
Dim myListMember As String
Dim sList As String
Dim x As Integer
Dim y As Integer
Dim iCount As Integer

myListMember = InputBox("Enter name of list member to be found")
Set myNameSpace = Application.GetNamespace("MAPI")
Set myFolder = myNameSpace.GetDefaultFolder(olFolderContacts)
Set myFolderItems = myFolder.Items
  iCount = myFolderItems.Count
   sList = ""
  For x = 1 To iCount
    If TypeName(myFolderItems.Item(x)) = "DistListItem" Then
  Set myDistList = myFolderItems.Item(x)
  For y = 1 To myDistList.MemberCount
      If InStr(1, myDistList.GetMember(y).Name, myListMember) Then
        'MsgBox myDistList.GetMember(y).Name & vbInformation, "Distribution List"
      If sList = "" Then
        sList = sList & myDistList.GetMember(y).Name & vbTab & myDistList.DLName
      Else
        sList = sList & vbCr & myDistList.GetMember(y).Name & vbTab & myDistList.DLName
      End If
      End If
    Next y
    End If
  Next x
    
   On Error Resume Next
    Set wdApp = GetObject(, "Word.Application")
    If Err Then
      Set wdApp = CreateObject("Word.Application")
    End If

   Set wdDoc = wdApp.Documents.Add
     wdApp.Visible = True
     wdApp.Activate
   With wdDoc.Range
    .InsertAfter sList
    .ParagraphFormat.TabStops.ClearAll
    .ParagraphFormat.TabStops.Add Position:=InchesToPoints(4), Alignment:=wdAlignTabLeft, Leader:=wdTabLeaderSpaces
   End With

Set wdDoc = Nothing
Set wdApp = Nothing
End Sub

Set References

You need to go to Tools, References (in the VBA Editor) and add Word as a reference.

In this screenshot, it lists Word 14. If you use an older version of Word, you'll have a different version here.