Dave offers this solution for Outlook users who want to open the Task module to a task list, instead of the To-Do list.

I have my Tasks set up in Tasks. I do not use the To-Do List. My Tasks are in Tasks, and I am constantly selecting that list to view, but Outlook thinks it should default back to the To-Do List, which is not where my Tasks are. How do I stop this from happening?

Our usual recommended solution is to create a custom view that includes only tasks and/or only tasks from a specific Tasks folder. This VBA solution does the same thing, by selecting a specific Task folder when you open the Task navigation module.

To use, add the following code to the top of the VB Editor's ThisOutlookSession.

To test the macro without restarting Outlook, click in the Application_Startup sub and click the Run button. Go back to Outlook, select the To-do folder then switch to Mail, then back to Tasks. The Tasks folder in the My Tasks section will be selected.

Macro to Use a Task Folder by Default

Open the VBA Editor using Alt+F11 and paste the following code in ThisOutlookSession. Click in the Startup sub and press Run to test it.

The index number in the following line controls which folder is selected when you switch to the Task Folder. This selects this second folder in the list. For example, to always use my "New Stuff" folder in the screenshot above, I'd change the index number to 5.
Set objNavFolder = objGroup.NavigationFolders.Item(2)

You'll need to sign the macro when you are done testing it or set Outlook's macro security to allow unsigned macros.

Dim WithEvents objPane As NavigationPane
 
Private Sub Application_Startup()
    Set objPane = Application.ActiveExplorer.NavigationPane
 
End Sub
 
 
Private Sub objPane_ModuleSwitch(ByVal CurrentModule As NavigationModule)
  Dim objModule As TasksModule
  Dim objGroup As NavigationGroup
  Dim objNavFolder As NavigationFolder
 
 If CurrentModule.NavigationModuleType = olModuleTasks Then
     Set objModule = objPane.Modules.GetNavigationModule(olModuleTasks)
     Set objGroup = objModule.NavigationGroups("My Tasks")

' Change the 2 to start in a different folder
     Set objNavFolder = objGroup.NavigationFolders.Item(2)
     objNavFolder.IsSelected = True
  End If
  Set objNavFolder = Nothing
  Set objGroup = Nothing
  Set objModule = Nothing
 End Sub

Use with any Navigation Module

You can use this macro with any navigation pane module by changing the 4 instances of "Tasks" to the appropriate module, folder type, or Group name.

How to use this macro

First: You will need macro security set to low during testing.

To check your macro security in Outlook 2010 or 2013, go to File, Options, Trust Center and open Trust Center Settings, and change the Macro Settings. In Outlook 2007 and older, it’s at Tools, Macro Security.

After you test the macro and see that it works, you can either leave macro security set to low or sign the macro.

Open the VBA Editor by pressing Alt+F11 on your keyboard.

To use the macro code in ThisOutlookSession:

1. Expand Project1 and double click on ThisOutlookSession.
2. Copy then paste the macro into ThisOutlookSession. (Click within the code, Select All using Ctrl+A, Ctrl+C to copy, Ctrl+V to paste.)

More information as well as screenshots are at How to use the VBA Editor