Task items have a button to send a Status Update; click this button to generate a message containing the details of the task.

If you always need to send the update to the same email addresses, you can use a macro to call the Status Report function and address the message.

Every day I send the same status report, to the same team, with the same one-line statement. The details of the task need to be in the body of the message, (not as an attachment) with an additional line of text from me.

This macro uses the Status Report function in an open Task to generate the email and Word functions to insert a note at the top. If you don't need to add a note you can remove Dim and Set lines used to access the Word editor and just send the status report.

Sub SendStatusReport()
 Dim myTask As Outlook.TaskItem
 Dim myinspector As Outlook.Inspector
 Dim myReport As Object

' used to insert message
Dim olDocument As Word.Document
Dim olSelection As Word.Selection

 Set myinspector = Application.ActiveInspector
 If Not TypeName(myinspector) = "Nothing" Then
 If TypeName(myinspector.CurrentItem) = "TaskItem" Then
 Set myTask = myinspector.CurrentItem
 Set myReport = myTask.StatusReport
 myReport.To = "me@domain.com"

 myReport.Display
 
' used to insert message
Set olDocument = myinspector.WordEditor
Set olSelection = olDocument.Application.Selection
 
olSelection.InsertBefore "This task is complete!"

' myReport.Send

 Else
 MsgBox "No task item is currently open."
 End If
 Else
 MsgBox "No inspector is currently open."
 End If
End Sub

Work with Open or Selected Task

To work with either an open or selected task item, you need to use the GetCurrentItem function.

Sub SendStatusReportAny()
 Dim myTask As Object
 Dim myReport As Object

' used to insert message
Dim olInspector As Outlook.Inspector
Dim olDocument As Word.Document
Dim olSelection As Word.Selection

Set myTask = GetCurrentItem()
On Error Resume Next

 If Not TypeName(myTask) = "TaskItem" Then
 MsgBox "Open or select a Task before running this macro!"
 Exit Sub
 End If
 
 Set myReport = myTask.StatusReport
 myReport.To = "me@domain.com"

 myReport.Display
 
' used to insert message
Set olInspector = Application.ActiveInspector()
Set olDocument = olInspector.WordEditor
Set olSelection = olDocument.Application.Selection
 
olSelection.InsertBefore "This task is complete!"

' myReport.Send

End Sub

Create your own status report

To compose your own Task status report, create the email message "from scratch" and add the Task fields to the message body. Like the previous macro, this one also uses the GetCurrentItem function.

Sub SendStatusReportNewMessage()
 Dim myTask As Object
 Dim myReport As Outlook.MailItem
 Dim strBody As String

Set myTask = GetCurrentItem()
On Error Resume Next
 If Not TypeName(myTask) = "TaskItem" Then
 
 MsgBox "Open or select a Task before running this macro!"
 Exit Sub
 End If

 strBody = "I finished this task!" & vbCrLf & _
 "Subject: " & myTask.Subject & vbCrLf & _
 "Task Date Completed: " & myTask.DateCompleted & vbCrLf & _
 "Task Complete: " & myTask.Complete & vbCrLf & _
 "Task notes: " & myTask.Body & vbCrLf & _
 "For : " & myTask.Companies & vbCrLf & _
 "Contacts: " & myTask.ContactNames & vbCrLf
 
 
 Set myReport = Application.CreateItem(olMailItem)
 
 With myReport
 
  .To = "me@domain.com"
  .Subject = myTask.Subject
  .Body = strBody
  .Display '.Send
End With

End Sub

How to use macros

First: You will need macro security set to low during testing.

To check your macro security in Outlook 2010 or 2013, go to File, Options, Trust Center and open Trust Center Settings, and change the Macro Settings. In Outlook 2007 and older, it’s at Tools, Macro Security.

After you test the macro and see that it works, you can either leave macro security set to low or sign the macro.

Open the VBA Editor by pressing Alt+F11 on your keyboard.

To put the code in a module:

1. Right click on Project1 and choose Insert > Module
2. Copy and paste the macro into the new module.

Add a button for the macro to an open Task form. Click the button to run the macro. More information as well as screenshots are at How to use the VBA Editor