Eric had a request to run rules based on a condition, in his case, when a message with a specific subject arrives.

If I send myself a message with a specific subject line I want outlook to execute a set of predefined rules already in my outlook client.

Sure, you can do this using a Run a Script rule.

1. Create the rules you want to run but do not enable them to run automatically.
2. Paste the RunRules macro below into a new module in Outlook's VB Editor.
3. Type your rule names into the olRuleNames array
4. Create a Rule that looks for a message with your specific subject line. Select Run a Script as the Action and select the RunRules macro.
   
5. Send yourself a test message.

Sub RunRules(Item As Outlook.MailItem)

Dim olRules As Outlook.Rules
Dim myRule As Outlook.Rule
Dim olRuleNames() As Variant
Dim name As Variant

' Enter the names of the rules you want to run       
olRuleNames = Array("SetCategory", "SetFlag", "MoveClutter")

Set olRules = Application.Session.DefaultStore.GetRules()

For Each name In olRuleNames()
    For Each myRule In olRules
    ' Rules we want to run
        If myRule.name = name Then
        myRule.Execute ShowProgress:=True
        End If
    Next
Next
End Sub

myRule.Execute supports 4 optional parameters. These are only needed if you don't want to use the defaults.

myRule.Execute ShowProgress:=True, Folder:=Session.GetDefaultFolder(olFolderInbox).Folders("my subfolder"), IncludeSubfolders:=True, RuleExecuteOption:=1

Run Rules when a Task Reminder Fires

If you prefer to run the rules on a schedule, use a task reminder to trigger the RunRules macro. Set up a recurring task called Run Rules and set a reminder. When the task reminder comes up, it triggers the RunRules macro.

This version of the RunRules macro can be triggered using a button on the ribbon or QAT

Private Sub Application_Reminder(ByVal Item As Object)
 
If Item.MessageClass <> "IPM.Task" Then
  Exit Sub
End If
 
If Item.Subject = "Run Rules" Then
  RunRules
End If

End Sub

Sub RunRules()

Dim olRules As Outlook.Rules
Dim myRule As Outlook.Rule
Dim olRuleNames() As Variant
Dim name As Variant
        
olRuleNames = Array("SetCategory", "SetFlag", "MoveClutter")

Set olRules = Application.Session.DefaultStore.GetRules()

For Each name In olRuleNames()
    For Each myRule In olRules
    ' Rules we want to run
        If myRule.name = name Then
        myRule.Execute ShowProgress:=True
        End If
    Next
Next
End Sub

Run Rules on a Secondary Inbox

If you want to run rules in a secondary account, you need to find the account using Outlook.Stores and add the Folder parameter. Because the folder is not in the default data file, you need to use GetFolderPath function.

Tip: Use the Folder parameter to run it on any folder. See "Working with VBA and non-default Outlook Folders" for more information on how to identify folders.

As written, this macro only runs when you run it. You can add it a ribbon button for easier access.

Sub RunRulesSecondary()

Dim oStores As Outlook.Stores
Dim oStore As Outlook.Store
     
Dim olRules As Outlook.Rules
Dim myRule As Outlook.Rule
Dim olRuleNames() As Variant
Dim name As Variant

' Enter the names of the rules you want to run
olRuleNames = Array("Rule 1 Name", "Rule 2 Name", "Rule 3 Name")

Set oStores = Application.Session.Stores
For Each oStore In oStores
On Error Resume Next

' use the display name as it appears in the navigation pane
If oStore.DisplayName = "alias@domain.com" Then

Set olRules = oStore.GetRules()
 
For Each name In olRuleNames()

    For Each myRule In olRules
       Debug.Print "myrule " & myRule
       
     If myRule.name = name Then

' inbox belonging to oStore
' need GetfolderPath functionhttp://slipstick.me/4eb2l
        myRule.Execute ShowProgress:=True, Folder:=GetFolderPath(oStore.DisplayName & "\Inbox")  

' current folder
'      myRule.Execute ShowProgress:=True, Folder:=Application.ActiveExplorer.CurrentFolder

       End If
    Next
Next

End If
Next
End Sub

How to use macros

First: You will need macro security set to low during testing.

To check your macro security in Outlook 2010 or 2013, go to File, Options, Trust Center and open Trust Center Settings, and change the Macro Settings. In Outlook 2007 and older, it’s at Tools, Macro Security.

After you test the macro and see that it works, you can either leave macro security set to low or sign the macro.

Open the VBA Editor by pressing Alt+F11 on your keyboard.

To put the code in a module:

1. Right click on Project1 and choose Insert > Module
2. Copy and paste the macro into the new module.

More information as well as screenshots are at How to use the VBA Editor