I want to create filtered views on the fly. The scenario: multiple projects, with a prefix in the subject identifying the project. I want to select a filter and apply it. I don't want to use Instant Search.

You can do this using a macro and a userform. The userform reads a text file stored on your hard drive, so it's easy to update the list when needed.

Use a UserForm to Select a Keyword

This macro sample loads a list of keywords in a userform. Run the macro and select the keyword to use in the filter.

1. Create a text file containing the keywords, one keyword (or phrase) per line. Add reset as one keyword to reset the view. (Table views will immediately show everything when you click reset; you need to leave the calendar and come back to see everything.)
2. Create a Userform with one ListBox and a Command button.
   
3. Right click on the Userform, choose View Code then paste the following macro into it.
4. Update the path to the text file in the macro.

This ViewFilterUserForm1 zip file has a sample UserForm (and the views macro), ready to Import into the VB Editor.

Private Sub UserForm_Initialize()
  Dim fn As String, ff As Integer, txt As String
    fn = "C:\Users\Diane\Documents\subject.txt" '< --- .txt file path
    txt = Space(FileLen(fn))
    ff = FreeFile
    Open fn For Binary As #ff
    Get #ff, , txt
    Close #ff

 Dim myArray() As String
  'Use Split function to return a zero based one dimensional array.
  myArray = Split(txt, vbCrLf)
  'Use .List method to populate listbox.
  ListBox1.List = myArray
lbl_Exit:
  Exit Sub

End Sub

 Private Sub ListBox1_DblClick(ByVal Cancel As MSForms.ReturnBoolean)
For lngCount = 0 To ListBox1.ListCount - 1
    If ListBox1.Selected(lngCount) = True Then
        strFilter = ListBox1.List(lngCount)
        
        End If
    Next
    
    Unload Me
 
lbl_Exit:
  Exit Sub
End Sub

Private Sub CommandButton1_Click()
For lngCount = 0 To ListBox1.ListCount - 1
    If ListBox1.Selected(lngCount) = True Then
        strFilter = ListBox1.List(lngCount)
        
        End If
    Next
    
    Unload Me
 
lbl_Exit:
  Exit Sub
End Sub

After adding the userform, right click on Project1 and choose Insert, Module. Paste the following macro in the new module.

To use this run this macro to load the userform. Either double click on the keyword or select it and click OK and the current view will show only items containing that keyword.

This macro works on any folder; Reset will clear the filter, however the calendar folder won't update until you leave the folder and come back to it.

This sample macro filters by a word in the subject EXPECT if the select word is Personal, then it filters by category. To use more words in the If statement, use a case statement.

The keyword filter is not case sensitive, the category filter is.

Public lstNum As Long
Public strFilter As String

Public Sub FilterView()

Dim objView As View

UserForm1.Show
Set objView = Application.ActiveExplorer.CurrentView

' keywords in subject
' not case sensitive
objView.Filter = Chr(34) & "urn:schemas:httpmail:subject" & Chr(34) & " LIKE '%" & strFilter & "%'"

' case sensitive
 If LCase(strFilter) = "personal" Then
 objView.Filter = Chr(34) & "urn:schemas-microsoft-com:office:office#Keywords" & Chr(34) & " = '" & strFilter & "'"
 End If
  
  Debug.Print objView.Filter
  objView.Save

 
' filter removed from calendar, does not refresh
' table views refresh
 If LCase(strFilter) = "reset" Then
  objView.Reset
End If
  objView.Apply
 
End Sub

Create a UserForm Video Tutorial

Use Macro Buttons

This version of the macro uses buttons on the ribbon. This sample uses different filters.

Dim strKeyword As String
Dim strFilter As String

Sub View1()
strKeyword = "search term"
strFilter = Chr(34) & "urn:schemas:httpmail:subject" & Chr(34) & " LIKE '%" & strKeyword & "%'"
FilterView2
End Sub

Sub View2()
strKeyword = "= 'Business'"
strFilter = Chr(34) & "urn:schemas-microsoft-com:office:office#Keywords" & Chr(34) & strKeyword
FilterView2
End Sub

Private Sub FilterView2()
 Dim objView As View

 Set objView = Application.ActiveExplorer.CurrentView

 objView.Filter = strFilter

  Debug.Print objView.Filter

 objView.Save
 objView.Apply
 
End Sub

How to use macros

First: You will need macro security set to low during testing.

To check your macro security in Outlook 2010 or 2013, go to File, Options, Trust Center and open Trust Center Settings, and change the Macro Settings. In Outlook 2007 and older, it’s at Tools, Macro Security.

After you test the macro and see that it works, you can either leave macro security set to low or sign the macro.

Open the VBA Editor by pressing Alt+F11 on your keyboard.

To put the code in a module:

1. Right click on Project1 and choose Insert > Module
2. Copy and paste the macro into the new module.

More information as well as screenshots are at How to use the VBA Editor