Outlook doesn't have a feature built in to prompt the sender to specify what folder a message should be saved in, but you can select the folder to save the message to before sending. Outlook has an option to save replies with the original when its not in the Inbox. If you want to be prompted each time, you'll need to use VBA or an add-in.

You can also use Rules to move sent messages to other folders. This works well if you need to move all messages sent to specific people or with specific words in the subject but won't work for one-off messages.

Note: The new Outlook for Windows app does not currently have an option to chose where to save sent messages.

Select the folder when sending the message | Use VBA to display a dialog
Save Replies with the Original | Using Rules to file Sent items
Tools

Select the folder when sending the message

You can select a different sent items folder for each message by selecting the folder from the Options dialog before sending the message.

In classic Outlook, select a different Sent Items folder using the Save Sent Item to Command on the Options ribbon.

If you are using the simplified ribbon in classic Outlook, the Save Sent item to command may be in the overflow, under the three dots on the right.

If you always want to use a different folder, you can use a macro to set the Save message to folder. You could use an If statement to only move certain messages to the folder.

This sample saves the sent message to a subfolder named "Diane" under the Sent Items folder.

Private Sub Application_ItemSend(ByVal Item As Object)
  Dim objNS As NameSpace
  Dim objFolder As MAPIFolder
  Set objNS = Application.GetNamespace("MAPI")
  Set objFolder = objNS.GetDefaultFolder(olFolderSentMail).Folders("Diane")
  Set Item.SaveSentMessageFolder = objFolder
  Set objFolder = Nothing
  Set objNS = Nothing
End Sub

Use VBA to display a dialog

These two macros use the ItemSend method in the macro above, but call the folder picker so you can choose a folder each time.

From the now-defunct Outlookcode.com:

This VBA code reproduces something closer to the Notes behavior by popping up the Select Folder dialog when the user sends the message.

This code demonstrates the use of the Namespace.PickFolder method to pop up the folder list for the user's selection. Note that you must handle the situation where the user cancels the dialog, in which case PickFolder returns Nothing.

The folder must be in your default information store -- Exchange mailbox or PST file. The IsInDefaultStore() function tests for this. If you need to move items to a different folder, the solution would be to use the ItemAdd event on the Sent Items folder's Items collection. See To quarantine application file attachments for an example of using ItemAdd.

To use this code, paste it into the built-in ThisOutlookSession module in VBA in Outlook. (Press Alt+F11 to open the VBA window.)

Private Sub Application_ItemSend(ByVal Item As Object, _
    Cancel As Boolean)
  Dim objNS As NameSpace
  Dim objFolder As MAPIFolder
  Set objNS = Application.GetNamespace("MAPI")
  Set objFolder = objNS.PickFolder
  If TypeName(objFolder) <> "Nothing" And _ 
     IsInDefaultStore(objFolder) Then
      Set Item.SaveSentMessageFolder = objFolder
  End If
  Set objFolder = Nothing
  Set objNS = Nothing
End Sub

Public Function IsInDefaultStore(objOL As Object) As Boolean
  Dim objApp As Outlook.Application
  Dim objNS As Outlook.NameSpace
  Dim objInbox As Outlook.MAPIFolder
  On Error Resume Next
  Set objApp = CreateObject("Outlook.Application")
  Set objNS = objApp.GetNamespace("MAPI")
  Set objInbox = objNS.GetDefaultFolder(olFolderInbox)
  Select Case objOL.Class
    Case olFolder
      If objOL.StoreID = objInbox.StoreID Then
        IsInDefaultStore = True
      End If
    Case olAppointment, olContact, olDistributionList, _
         olJournal, olMail, olNote, olPost, olTask
      If objOL.Parent.StoreID = objInbox.StoreID Then
        IsInDefaultStore = True
      End If
    Case Else
      MsgBox "This function isn't designed to work " & _
             "with " & TypeName(objOL) & _
             " items and will return False.", _
             , "IsInDefaultStore"
  End Select
  Set objApp = Nothing
  Set objNS = Nothing
  Set objInbox = Nothing
End Function

If you want the user to pick a folder only when the item is sent through a specific account, you will need to structure the code as a procedure that Rules Wizard can run, rather than as an Application-level event handler. You can call the SetSaveFolder code below from a "run a script" action on an Outlook rule. The condition on the rule should be "through specified account."

Public Sub SetSaveFolder(ByVal Item As MailItem)
  Dim objNS As NameSpace
  Dim objFolder As MAPIFolder
  Set objNS = Application.GetNamespace("MAPI")
  Set objFolder = objNS.PickFolder
  If TypeName(objFolder) <> "Nothing" And _ 
     IsInDefaultStore(objFolder) Then
      Set Item.SaveSentMessageFolder = objFolder
  End If
  Set objFolder = Nothing
  Set objNS = Nothing
End Sub

Another variation would be to not save the item at all if the user doesn't choose a folder. You can do that by setting the DeleteAfterSubmit property to True.

Note: VBA does not work on messages created with File, Send commands in other applications or the Send to command in Windows Explorer. Send to commands use Simple MAPI, which bypasses Outlook functionality.

Use VBA to move sent items

You can use a macro to move all items sent by a specific email account. See Use a macro to move sent items for the VBA code sample. This macro will work with messages created using the File, Send commands in other applications since it processes the message after it's sent.

Save Replies with the original

If you move messages out of the Inbox, you can configure Outlook (all versions) to save replies with the original.

In Outlook 2010 and up, go to File, Options, Mail - about halfway down, in the Save Messages section, is the option to save replies with the original when its not in the Inbox.

Using Rules to file Sent items

You can create an After Sending rule to copy messages meeting specific conditions or to specific persons to a different sent folder, however, this copies the sent message. The only way to avoid saving a message in the Sent folder as well as in another folder is by disabling the option to Save all sent messages and use rules to save messages. If you use this method, your first rule(s) will save messages meeting specific conditions in the desired folders, with each rule containing the Stop processing action. The final rule applies to all messages and saves them in the Sent folder, catching all messages not processed by previous After sending Rules.

Step 1: Begin by creating a rule "from scratch", choosing a blank rule, applied on messages you send:

Step 2: Add your conditions and Actions, remembering to select Stop processing on each rule.

Step 3: The final Rule will have no conditions; the Action will copy messages to the Sent folder:

Note that when you use a rule to move a copy of the sent item, its marked as unread. You will need to use VBA to mark the copied sent message read. See Mark Sent Items “Read” after Moving to a New Folder for the necessary code.