What I'm looking for is to grab the table data and dump it in the same work book and sheet as new emails come in.

Using the macros on this page, when table data is received in an email, the table can be copied to an Excel worksheet.

This sample email has two tables (and a short message), we're copying the contents of the last table into Excel.

These are the results. The table values from additional emails would be added to after the last used row.

Note: if there are blank cells in the table, the contents of the row may paste into the wrong cell.

While the examples on this page copy the data in the second table only, you can get the data from all tables by using For x = 1 To doc.Tables.Count (and the matching Next) in place of x = doc.Tables.Count.

This version of the macro runs on the selected message(s). It saves the contents of the last table to a workbook stored in the user's Documents folder.

Sub SaveEmailTablestoExcel()
Dim Item As MailItem, x%
Dim r As Object  'As Word.Range
Dim doc As Object 'As Word.Document
Dim iRow As Long 'row index
Dim xlApp As Object, xlWB As Object
Dim xlSheet As Object
Dim strPath As String
Dim bXStarted As Boolean

Dim enviro As String
enviro = CStr(Environ("USERPROFILE"))
'the path of the workbook
 strPath = enviro & "\Documents\Book1.xlsx"
     On Error Resume Next
     Set xlApp = GetObject(, "Excel.Application")
     If Err <> 0 Then
         Application.StatusBar = "Please wait while Excel source is opened ... "
         Set xlApp = CreateObject("Excel.Application")
         bXStarted = True
     End If
     On Error GoTo 0
     'Open the workbook to input the data
     Set xlWB = xlApp.Workbooks.Open(strPath)
' Get sheet by name
     Set xlSheet = xlWB.Sheets("Sheet1")
' Get sheet by index #
     ' Set xlSheet = xlWB.Sheets(1)

xlApp.Visible = True

For Each Item In Application.ActiveExplorer.Selection
Set doc = Item.GetInspector.WordEditor
' to get all tables
 '   For x = 1 To doc.Tables.Count
' Get last table
     x = doc.Tables.Count
     Set r = doc.Tables(x)
'rows 2 - end
     For iRow = 2 To r.Rows.Count
         r.Rows(iRow).Range.Copy
'to get entire table
     ' r.Range.Copy

       xlSheet.Paste
       xlSheet.Cells(xlSheet.Rows.Count, 1).End(3).Offset(1).Select
    Next
Next
xlWB.Save

' close workbook
xlWB.Close 1
If bXStarted Then
    xlApp.Quit
End If

End Sub

Run a Script Rule

This is a run a script rule. It copies last table in the message to a new Excel workbook.

Outlook 2013 and 2016's Run a script rule is missing from all builds released after June 2017. To restore the run a script option, you need to set a registry key. See "Run-a-Script Rules Missing in Outlook" for more information.

Sub CopyTabletoExcel(Item As Outlook.MailItem)
Dim r As Object  'As Word.Range
Dim doc As Object 'As Word.Document
Dim iRow As Long 'row index
Dim xlApp As Object, xlWB As Object
Dim xlSheet As Object
Dim strPath As String
Dim bXStarted As Boolean

Dim enviro As String
enviro = CStr(Environ("USERPROFILE"))

'the path of the workbook
 strPath = enviro & "\Documents\Book1.xlsx"
     On Error Resume Next
     Set xlApp = GetObject(, "Excel.Application")
     If Err <> 0 Then
         Application.StatusBar = "Please wait while Excel source is opened ... "
         Set xlApp = CreateObject("Excel.Application")
         bXStarted = True
     End If
     On Error GoTo 0
     'Open the workbook to input the data
     Set xlWB = xlApp.Workbooks.Open(strPath)
'get sheet by name
Set xlSheet = xlWB.Sheets("Sheet1")

xlApp.Visible = True

Set doc = Item.GetInspector.WordEditor
' to get all tables
 '   For x = 1 To doc.Tables.Count
' Get last table
     x = doc.Tables.Count
     Set r = doc.Tables(x)
'rows 2 - end
     For iRow = 2 To r.Rows.Count
         r.Rows(iRow).Range.Copy
'to get entire table
     ' r.Range.Copy

       xlSheet.Paste
       xlSheet.Cells(xlSheet.Rows.Count, 1).End(3).Offset(1).Select
    Next

xlWB.Save

' close workbook
xlWB.Close 1
If bXStarted Then
    xlApp.Quit
End If

End Sub

How to use the macros on this page

First: You need to have macro security set to low during testing. The macros will not work otherwise.

To check your macro security in Outlook 2010 and newer, go to File, Options, Trust Center and open Trust Center Settings, and change the Macro Settings. In Outlook 2007 and older, look at Tools, Macro Security.

After you test the macro and see that it works, you can either leave macro security set to low or sign the macro.

Some macros need to be in ThisOutlookSession, others go into a module or can be placed in either ThisOutlookSession or a module. The instructions are below.

Open the VBA Editor by pressing Alt+F11 on your keyboard.

To put the code in a module:

1. Right click on Project1 and choose Insert > Module
2. Copy and paste the macro into the new module.

More information as well as screenshots are at How to use the VBA Editor