The code samples on this page will get the category names, color, and shortcuts assigned. Once you have this list, you can use the second code sample to restore the list to a different computer. If you want a simple list of your categories and color names that are assigned, see Print a list of Outlook Categories and their Colors. For a list of utilities you can use to manage your color categories, see the Tools section at Outlook Categories and Color Categories.

Step 1: Get a formatted list of color categories.
Step 2: Add the formatted list to the AddCategory Macro and run the macro

Begin by running the GetCategoryNames macro. Press Ctrl+G to open the Immediate window then select all and copy the list. Paste the list into Notepad or a plain text email message.

If the categories names are not unique, the macro AddCategory macro will fail. You can use the DeleteCategories macro to remove all categories before adding your list of categories

Private Sub GetCategoryNames()
    Dim objNS As NameSpace
    Dim objCat As Category
    Dim strOutput As String
    
    Set objNS = Application.GetNamespace("MAPI")
    
    If objNS.Categories.Count > 0 Then
        
        For Each objCat In objNS.Categories
           strOutput = strOutput & "AddCategory """ & objCat.Name & """, " _
           & objCat.Color & ", " & objCat.ShortcutKey & vbCrLf

' to remove categories as you make a list
' uncomment this line
'objNS.Categories.Remove (objCat.CategoryID)
        Next
    End If
    
    ' Print the list to the Immediate Window
    ' Press Ctrl+G to open it or use View > Immediate Window
   Debug.Print strOutput

'if you have a lot of categories, the immediate window won't be sufficient       
       Open "C:\mycategories.txt" For Append As 1
       Print #1, strOutput
       Close #1
    
    ' Clean up.
 Set objCat = Nothing
 Set objNS = Nothing
End Sub

Restore the color categories list

Copy the list created by the code above and paste it into this code sample, in place of
AddCategory "category", 17, 0

Then run the RestoreCategories macro. The On Error Resume Next line will allow you to add a category list that includes categories already in your master category list, however, the category color won't be updated if the old categories aren't removed.

Public Sub RestoreCategories()

   AddCategory "category", 17, 0

End Sub

Private Sub AddCategory(strCategoryName As String, intColor As Integer, intKey As Integer)
    Dim objNS As NameSpace
 
    Set objNS = Application.GetNamespace("MAPI")
       On Error Resume Next
    objNS.Categories.Add strCategoryName, intColor, intKey
    Set objNS = Nothing
End Sub

Restore a text file

This version of RestoreCategories code will read the categories from a text file. You'll either need to edit the text file to remove AddCategory from each line and the quotes from around the category name or create a text file without them.

To create the text file without AddCategory or quotes around the name, change the strOutput line in the GetCategoryNames macro to this

strOutput = strOutput & objCat.name & "," _
           & objCat.Color & ", " & objCat.ShortcutKey & vbCrLf

Public Sub RestoreCategories()
Dim objNS As NameSpace
Dim FileNum As Integer
Dim current_cat As String
Dim splitCategory() As String
    
Set objNS = Application.GetNamespace("MAPI")
  On Error Resume Next

FileNum = FreeFile()
Open "C:\mycategories.txt" For Input As #FileNum

While Not EOF(FileNum)
  Line Input #FileNum, current_cat
   splitCategory = Split(current_cat, ",")

' use text file, no quotes around name
objNS.Categories.Add splitCategory(0), splitCategory(1), splitCategory(2)
Wend
Close FileNum

End Sub

VBScript version to add categories

This is a VBScript version of the macro above.

Dim objOutlook, objNS, objFolder
Set objOutlook = CreateObject("Outlook.Application")
Set objNS = objOutlook.GetNamespace("MAPI")
Dim get_cat
Dim splitCategory
 
Set objFileToRead = CreateObject("Scripting.FileSystemObject").OpenTextFile("D:\Documents\categories.txt",1)
do while not objFileToRead.AtEndOfStream
get_cat= objFileToRead.ReadLine()
splitCategory = Split(get_cat, ",")
'If already exists, skip 
On Error Resume Next 
' use text file, no quotes around category name
objNS.Categories.Add splitCategory(0), splitCategory(1), splitCategory(2)
loop
objFileToRead.Close
Set objFileToRead = Nothing

Using the GetCategoryNames and RestoreCategories Macros

The following video tutorial shows how to use the two macros above to create a list of your categories and their color then add those categories to Outlook. You can use these macros to share category names and colors with other Outlook users.

Delete color categories

To delete the existing categories and add the categories in your list, paste the following code into the VBA editor and add DeleteCategories as the first line of the RestoreCategories procedure:

Public Sub RestoreCategories()
   DeleteCategories
   AddCategory "category", 17, 0
End Sub

Warning: using the DeleteCategories procedure will delete all categories from the list.

Private Sub DeleteCategories()
    Dim objNS As NameSpace
    Dim objCat As Category
   
    Set objNS = Application.GetNamespace("MAPI")
   
    If objNS.Categories.Count > 0 Then
       
        For Each objCat In objNS.Categories
            objNS.Categories.Remove (objCat.CategoryID)
        Next
       
    End If
       
    Set objCat = Nothing
    Set objNS = Nothing
   
End Sub

While I recommend using the RestoreCategories code if you need to work with a lot of categories, if you want to add or remove a single category within a macro, you can do it with one line (for each action and category).

If you need to change the category color, you'd first remove it then add it back. The categories already assigned are not affected, the category is removed only from the master category list.

Sub AddRemoveCategories()
    Session.Categories.Remove ("Category2")
    Session.Categories.Add "Category2", 13, 0
End Sub

Get the Categories from All Mailboxes in Profile

This code sample reads every data file in an Outlook profile and grabs the category names, colors and shortcut key, writing the lists to the Immediate window (Ctrl+G) in the format needed by the restore categories macro.

Private Sub GetCategoryNamesinAllAccounts()
    Dim oStores As Outlook.Stores
    Dim oStore As Outlook.Store
    Dim oCategories As Outlook.Categories
    Dim oCategory As Outlook.Category
    Dim strOutput As String
    
    Set oStores = Application.Session.Stores
 
    For Each oStore In oStores
        Set oCategories = oStore.Categories

        If oCategories.Count > 0 Then
        For Each oCategory In oCategories
             strOutput = strOutput & "AddCategory """ & oCategory.Name & """, " _
           & oCategory.Color & ", " & oCategory.ShortcutKey & vbCrLf
        Next
        End If
     
        strOutput = oStore.DisplayName & vbCrLf _
        & "--------------Categories-----------------" & vbCrLf _
        & strOutput
        Debug.Print strOutput

'if you have a lot of categories, the immediate window won't be sufficient       
       Open "C:\mycategories.txt" For Append As 1
       Print #1, strOutput
       Close #1
 
       strOutput = ""

    Next

 Set oStores = Nothing
 Set oStore = Nothing
 Set oCategories = Nothing
 Set oCategory = Nothing
 
End Sub

Set Uniform Categories on All Accounts in Profile

By putting the macros above together, you can create a macro that reads all categories in all accounts in the profile, saving them to a text file, then imports a list of categories to all accounts. In addition, if you need some categories unique to an account, you can set an If statement and add categories only to that account.

Because all of the code needed to do this is listed above (in the Get the Categories from All Mailboxes and RestoreCategories macros), I'm only going to link to a text file containing the macro.

Copy and paste the code into a module, then run the GetCategoryNamesinAllAccounts macro which creates a text file containing all of the category names. You can clean up this list in Excel - paste it into Excel then sort and delete duplicate categories.

After the list is cleaned up, paste it in the AddCategoriesToAllStores macro and run it.

set-uniform-categories

Category Colors by number

The following is a list of the category colors and their index number. Outlook 365 has brighter colors and some new color names, which are noted in the table.